|
|
[@推广大使]
{
<ImgEx:36:233:233:234:530:-16/@关闭对话框>
#act
OpenBigDialogBox 35 52
CreateFile ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\推广码文本\<$username>的推广码文本.txt
CreateFile ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\绑定码文本\<$username>的绑定码文本.txt
CreateFile ..\QuestDiary\推广系统\玩家可领取奖励次数\<$username>的推广奖励次数.txt
CreateFile ..\QuestDiary\推广系统\已经生成的推广码.txt
CreateFile ..\QuestDiary\推广系统\查询绑定自己的玩家\绑定玩家【<$username>】的名单.txt
goto @获取自身推广码
goto @获取绑定的推广码信息
goto @获取可以领取推广奖励次数
#say
<>\
达到【<70/scolor=250>】级后可以成为推广大使，点击“生成我的推广码”可以生成属于你自己的推广码\
每个玩家的推广码是<独一无二/scolor=250>的,每有一个绑定你推广码的人达到600级后，你将可以领取\
【10万】元宝/人次，绑定的人数无上限，绑定人数越多你将获得越丰厚的奖励！\
<【提示】:每个号仅能绑定一个推广码！不能绑定自身的推广码/scolor=253>\
<>\
您的推广码为：【<$str(S30)>】\<>\<>\
您绑定的推广码为：【<$str(S31)>】\<>\<>\
您绑定的推广码玩家名字为：【<$str(S32)>】\<>\<>\
您当前可以领取的推广奖励次数为：【<$str(S33)>】次\<>\<>\
【<领取推广奖励/@领取推广奖励>】< >【<查询绑定自己的玩家/@查询绑定自己的玩家>】
;==========================================
[@查询绑定自己的玩家]
#act
GetListString ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\推广码文本\<$username>的推广码文本.txt 0 <$STR(S60)>
#if
equal S60
#act
messagebox 你还未生成推广码，无法查询！
break
#if
#act
mov D20 0
goto @循环查询绑定自己的玩家
[@循环查询绑定自己的玩家]
#act
GetListString ..\QuestDiary\推广系统\查询绑定自己的玩家\绑定玩家【<$username>】的名单.txt <$str(D20)> <$STR(S50)>
#if
equal S50
#act
goto @是否没人绑定
break
#if
#act
INC D20 1
sendmsg 5 255 0 ===================当前绑定您的玩家【<$str(D20)>】为：【<$str(S50)>】=============================
goto @循环查询绑定自己的玩家
[@是否没人绑定]
#if
equal D20 0
#act
sendmsg 5 当前还没有玩家绑定您的推广码！快去召集你的小伙伴一起玩吧！
;==========================================
[@获取自身推广码]
#act
GetListString ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\推广码文本\<$username>的推广码文本.txt 0 <$STR(S30)>
#if
equal S30
#act
mov S30 <生成我的推广码/@生成我的推广码>
#elseact
mov S30 {<$str(S30)>/scolor=250}
;--------------------------------------------------生成自身推广码
[@生成我的推广码]
#if
checklevel 70
#act
mov S40
GetRandomText ..\QuestDiary\推广系统\随机码\随机.txt S41
INC S40 <$str(S41)>
GetRandomText ..\QuestDiary\推广系统\随机码\随机.txt S41
INC S40 <$str(S41)>
GetRandomText ..\QuestDiary\推广系统\随机码\随机.txt S41
INC S40 <$str(S41)>
GetRandomText ..\QuestDiary\推广系统\随机码\随机.txt S41
INC S40 <$str(S41)>
GetRandomText ..\QuestDiary\推广系统\随机码\随机.txt S41
INC S40 <$str(S41)>
GetRandomText ..\QuestDiary\推广系统\随机码\随机.txt S41
INC S40 <$str(S41)>
goto @检测是否有重复推广码
#elseact
messagebox 成为推广大使需要至少70级！
[@检测是否有重复推广码]
#if
CHECKTEXTLIST ..\QuestDiary\推广系统\已经生成的推广码.txt <$str(S40)>
#act
sendmsg 6 推广码重复，正在重新生成！
goto @生成我的推广码
#elseact
mov S30 <$str(S40)>
AddTextListEx ..\QuestDiary\推广系统\已经生成的推广码.txt <$str(S30)> 0
AddTextListEx ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\推广码文本\<$username>的推广码文本.txt <$str(S30)> 0
CreateFile ..\QuestDiary\推广系统\推广码查询玩家\推广码【<$str(S30)>】的玩家名字.txt
AddTextListEx ..\QuestDiary\推广系统\推广码查询玩家\推广码【<$str(S30)>】的玩家名字.txt <$username> 0
sendmsg 6 您的推广码生成成功！为【<$str(S30)>】
goto @推广大使
;==========================================
[@获取绑定的推广码信息]
#act
GetListString ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\绑定码文本\<$username>的绑定码文本.txt 0 <$STR(S31)>
#if
equal S31
#act
mov S31 <绑定推广码/@@InPutString21>
mov S32 <未绑定任何玩家/scolor=250>
#elseact
GetListString ..\QuestDiary\推广系统\推广码查询玩家\推广码【<$str(S31)>】的玩家名字.txt 0 <$STR(S32)>
mov S31 {<$str(S31)>/scolor=250}
mov S32 {<$str(S32)>/scolor=250}
;---------------------------------------------------绑定推广码
[@InPutString21]
#if
equal S21
#act
messagebox 请输入推广码!
break
#if
CHECKTEXTLIST ..\QuestDiary\推广系统\已经生成的推广码.txt <$str(S21)>
#act
goto @检测是否自身推广码
#elseact
messagebox 推广码不存在，请重新输入！
[@检测是否自身推广码]
#act
GetListString ..\QuestDiary\推广系统\推广码查询玩家\推广码【<$str(S21)>】的玩家名字.txt 0 <$STR(S42)>
#if
equal S42 <$username>
#act
messagebox 请不要绑定自身的推广码！
#elseact
AddTextListEx ..\QuestDiary\推广系统\玩家自身推广码和绑定的推广码\绑定码文本\<$username>的绑定码文本.txt <$str(S21)> 0
AddTextListEx ..\QuestDiary\推广系统\查询绑定自己的玩家\绑定玩家【<$STR(S42)>】的名单.txt <$username> 0
sendmsg 6 您成功绑定了推广码【<$str(S21)>】，该玩家为【<$STR(S42)>】！
goto @推广大使
Gmexecute 开始提问 @推广码检查是否600级
;==========================================
[@获取可以领取推广奖励次数]
#act
GetListString ..\QuestDiary\推广系统\玩家可领取奖励次数\<$username>的推广奖励次数.txt 0 <$STR(D33)>
mov S33 {<$STR(D33)>/scolor=250}
;==========================================
[@领取推广奖励]
#act
GetListString ..\QuestDiary\推广系统\玩家可领取奖励次数\<$username>的推广奖励次数.txt 0 <$STR(D33)>
#if
large D33 0
#act
gamegold + 100000
sendmsg 6 元宝+100000
sendmsg 0 ----感谢【<$username>】您的推广，由于您推荐的玩家达到【600】级,奖励您【10万】元宝！----
SendTopMsg 0 249 ----感谢【<$username>】您的推广，由于您推荐的玩家达到【600】级,奖励您【10万】元宝！---- 1
DEC D33 1
AddTextListEx ..\QuestDiary\推广系统\玩家可领取奖励次数\<$username>的推广奖励次数.txt <$str(D33)> 0
goto @推广大使
#elseact
messagebox 您没有可领取奖励的次数！
;==========================================
[@关闭对话框]
#IF
#ACT
Close
CloseBigDialogBox
}
|
|
发表于 2023-11-21 15:49:14
发表于 2023-11-21 15:59:23
